OTAYORI

楽天市場経済圏を彷徨うブログ

【Google Spread Sheet】Query関数 例文チートシート

日付の指定

=QUERY(A:B, "SELECT A WHERE B= DATE 'YYYY-MM-DD'", 0)

別シートの参照

=QUERY(A5:C10, "SELECT B WHERE A=" & E5, 0)

全件表示

=QUERY(A:C,”SELECT *”)

条件検索

文字列の場合

=QUERY(A:C,”SELECT * WHERE A = ‘請求書'”)

数値の場合

=QUERY(A:C,”SELECT * WHERE A = 0”)

条件検索(複数) & 上位件数表示

=QUERY(A:C,”SELECT * WHERE A = ‘請求書’ AND B >= 200 ORDER BY B DESC LIMIT 5″)

集計関数&別名表示

=QUERY(A:C,”SELECT SUM(B) WHERE A = ‘請求書’ LABEL SUM(B) ‘請求額合計'”)

単純な範囲の結合方法

単純に範囲Aの下に範囲Bを結合する場合、下記のような表現をします。 ={範囲A;範囲B}
={B3:E8;G3:J8}

結合した範囲に対してQUERY関数を使う方法

結合した範囲に対するQUERY関数では「Col1」「Col2」…を使う
=QUERY({B3:E8;G3:J8},"WHERE Col3 = '請求書'")

※1列目は「Col0(ゼロ)」ではなく「Col1」だということに注意して番号を振る。

結合した複数のQUERY関数を範囲としたQUERY関数の使い方

=QUERY({
QUERY(範囲A,条件A);
QUERY(範囲B,条件B)},
条件C)

=QUERY({
QUERY(B3:E8,"WHERE D ='注文書'");
QUERY(G3:J8,"WHERE I='請求書'")},
"WHERE Col4 > 100")

IMPORTRANGE関数とQUERY関数で、複数の別シートの範囲を結合する方法

=QUERY({
IMPORTRANGE(シートURL,シート範囲);
IMPORTRANGE(シートURL,シート範囲)},
"WHERE 条件")

複数の別シートの範囲を結合する例

=QUERY({
IMPORTRANGE("シートURL","シート115!B3:E8");
IMPORTRANGE("シートURL","シート115!G3:J8")},
"WHERE Col3='請求書'")